Gecko [ c.stage.kornherr.net ]

Name	Size	Permission	Date
README.getmail	2.45 KB	-rw-r--r--	2019-08-20 23:00
README.gz	3.27 KB	-rw-r--r--	2019-10-25 16:42
delete-later	1.78 KB	-rw-r--r--	2019-08-20 23:00
delete-later.README.gz	2.28 KB	-rw-r--r--	2019-08-20 23:00
domino	2.42 KB	-rw-r--r--	2019-08-20 23:00
fetchmail-mode.el.gz	2.1 KB	-rw-r--r--	2019-10-25 16:42
fetchmail.logrotate	2.13 KB	-rw-r--r--	2025-10-08 11:40
fetchmaildistrib	977 B	-rw-r--r--	2019-08-20 23:00
fetchmailnochda.pl.gz	1.67 KB	-rw-r--r--	2019-08-20 23:00
fetchsetup	3.62 KB	-rw-r--r--	2022-08-04 13:03
getmail	2.12 KB	-rw-r--r--	2019-08-20 23:00
gotmail	2.31 KB	-rw-r--r--	2019-08-20 23:00
gotmail.awk	1.52 KB	-rw-r--r--	2019-08-20 23:00
gotmail.conf	614 B	-rw-r--r--	2019-08-20 23:00
gotmail.html.awk	2.96 KB	-rw-r--r--	2019-08-20 23:00
login	334 B	-rw-r--r--	2019-08-20 23:00
logout	844 B	-rw-r--r--	2019-08-20 23:00
maildaemon	2.38 KB	-rw-r--r--	2019-08-20 23:00
mailqueue.pl.gz	5.05 KB	-rw-r--r--	2019-08-20 23:00
multidrop.gz	3.75 KB	-rw-r--r--	2019-08-20 23:00
novell	2.2 KB	-rw-r--r--	2019-08-20 23:00
poptest	2.4 KB	-rw-r--r--	2019-08-20 23:00
preauth-harness	1.41 KB	-rw-r--r--	2019-08-20 23:00
runfetchmail.gz	2.55 KB	-rw-r--r--	2022-08-04 13:03
toprocmail	917 B	-rw-r--r--	2019-08-20 23:00
zsh-completion	868 B	-rw-r--r--	2019-08-20 23:00

Rename

#!/usr/bin/perl -w
# correct-domino-mime-conversion - does it!
# $Id: domino,v 1.1 2004/06/08 03:59:00 rfunk Exp $

use strict;

# Any arguments are expected to be an mda invocation.
if (@ARGV) {
    my $mda = join(' ', @ARGV);
    open(MDA, "| $mda") or die "Can't exec $mda: $!\n";
    select(MDA);
}

# Look for a Boundary declaration in the message header
my $decltag;
while (<STDIN>) {
    print;
    if (/boundary=\"(.*)\"$/i) {
	$decltag = $1;
    } elsif (/^$/) {
	# An empty line marks the end of the headers.
	last;
    }
}

# If we didn't find a Boundary declaration just pipe the rest of the
# message unchanged.
if (!defined $decltag) {
    while (<STDIN>) {
	print;
    }
    exit 0;
}

# Substitute $decltag for every ocurrence of an outer-level boundary
# string found in the body of the message.
my $usedtag;
while (<STDIN>) {
    if (/^--(.*)$/) {
	$usedtag = $1 unless defined $usedtag;
	if ($1 eq $usedtag) {
	    $_ =  "--$decltag\n";
	} elsif ($1 eq "$usedtag--") {
	    $_ = "--$decltag--\n";
	}
    }
    print;
}

=pod

This script can be used to bypass a bug in the Domino-5.0.2b IMAP
service that manifests itself when you use fetchmail as the IMAP
client.  The problem is that fetchmail (differently from other IMAP
clients) fetches messages in two parts, first the headers and then the
body.  It seems that Domino converts the messages from its internal
format into MIME twice.  In doing so, it declared a boundary string in
the messages Content-type header and uses another one to separate the
parts in the body.

This script should be used as a mda option for fetchmail.  As
arguments to it, pass the former mda you used.  I, for example, use the following entry in my .fetchmailrc:

poll server ... mda "/usr/bin/procmail -d %T";

To use this filter, I changed the above into the following:

poll server ... mda "/home/gustavo/bin/correct-domino-mime-conversion /usr/bin/procmail -d %T";

If you do not use a mda normally, you can try the following to call sendmail directly:

poll server ... mda "/home/gustavo/bin/correct-domino-mime-conversion //wherever/is/your/sendmail -oem -f %F %T";

Without argumets this script is a filter that reads from its stdin and
outputs the result into its stdout.

I should mention that this bug seems to be solved in Domino 5.0.3
(http://www.notes.net/46dom.nsf/434e319a66960d8385256857005cd97b/4499e0db6e43732b852568b2006ef7e9?OpenDocument)
but I have not checked it.

Gustavo.
<gustavo@cpqd.com.br>

=cut